;CLIPCOSYSP
;avance-version (10/02/12)
;Clean In-phase COSY
;2D H-1/H-1 correlation using in-phase transfer
;phase sensitive using states processing
;using shaped pulses for all pulses
;
;$CLASS=HighRes
;$DIM=2D
;$TYPE=
;$SUBTYPE=
;$COMMENT=

#include <Avance.incl>
#include <Grad.incl>
#include <Delay.incl>

"d4=1s/(cnst2*4)"
"d11=30m"
"in0=inf1"
"d0=in0/2"
"acqt0=0"

1 ze
2 d11 
  d1 pl0:f1

;begin experiment
  (p13:sp13 ph1):f1 ;BEBOP
  d0 UNBLKGRAD

;first filter block
  (p13:sp16 ph10):f1  ;BEBOP
  4u 
  4u gron1
  (p23:sp23 ph8):f1 
  4u groff
  d16
  (p13:sp13 ph2):f1 ;BEBOP
  
;in-phase transfer block, planar mixing
  d4
  (p14:sp14 ph20):f1 ;UR180
  d4
  (p15:sp15 ph20):f1 ;UR90
  d4
  (p14:sp14 ph3):f1 ;UR180
  d4

;second filter block
  (p13:sp16 ph21):f1 ;tr BEBOP
  4u gron2 
  (p24:sp24 ph9):f1
  40u groff
  p16:gp3 ;gradient to prevent complete refocusing  
  d16
  1m BLKGRAD
  (p13:sp13 ph4):f1 ;BEBOP

;acquisition
  go=2 ph31 
  d11 mc #0 to 2 
     F1PH(calph(ph1, +90), caldel(d0, +in0))
exit 
  

;excitation, states, TPPI
ph1 = 0 0 0 0 2 2 2 2 2 2 2 2 0 0 0 0
ph10= 0
;shape pulse phase (z-filter)
ph8 = 0 1 0 1 1 0 1 0 3 2 3 2 2 3 2 3
ph9 = 2 3 2 3 3 2 3 2 1 0 1 0 0 1 0 1
;transfer block phases
ph2 = 0
ph20= 1 3 3 1
ph3 = 3 2 3 2; any phase
ph21= 0 0 2 2
;readout/receiver phase
ph4 = 0 ; any phase
ph31= 0 2 2 0 2 0 0 2 2 0 0 2 0 2 2 0




;PHASEN WURDEN AN DIE OCT-PULSOPTIMIERUNG-PHASENSCHEISZE ANGEPASST!
;ph2 und 21 wurde um 1 verringert, um die effektive Drehachse beim BEBOP ;zu korrigieren (BEBOP z->x ph0 ist so ähnlich wie 90°y-Puls)

#ifdef PCYCLE0
;excitation, states, TPPI
ph1 = 0 
ph10= 0
;shape pulse phase (z-filter)
ph8 = 0
ph9 = 2
;transfer block phases
ph2 = 0
ph20= 1
ph3 = 3; any phase
ph21= 0
;readout/receiver phase
ph4 = 0 ; any phase
ph31= 0 
#endif

#ifdef PCYCLE1
;excitation, states, TPPI
ph1 = 0 
ph10= 0
;shape pulse phase (z-filter)
ph8 = 0 1 3 2
ph9 = 2 3 0 1
;transfer block phases
ph2 = 0
ph20= 1 3 3 1
ph3 = 3 2 3 2; any phase
ph21= 0 0 2 2
;readout/receiver phase
ph4 = 0 ; any phase
ph31=0 2 2 0
#endif

#ifdef PCYCLE2
;excitation, states, TPPI
ph1 = 0 2 2 0 
ph10= 0
;shape pulse phase (z-filter)
ph8 = 0 1 3 2
ph9 = 2 3 0 1
;transfer block phases
ph2 = 0
ph20= 1
ph3 = 3; any phase
ph21= 0
;readout/receiver phase
ph4 = 0 ; any phase
ph31=0 2 2 0
#endif

#ifdef PCYCLE3
;excitation, states, TPPI
ph1 = 0 
ph10= 0 2 2 0
;shape pulse phase (z-filter)
ph8 = 0 1 3 2
ph9 = 2 3 0 1
;transfer block phases
ph2 = 0
ph20= 1
ph3 = 3; any phase
ph21= 0 2 0 2
;readout/receiver phase
ph4 = 0 ; any phase
ph31= 0 0 2 2
#endif

#ifdef PCYCLE4
;excitation, states, TPPI
ph1 = 0 
ph10= 0
;shape pulse phase (z-filter)
ph8 = 0 1 3 2
ph9 = 2 3 0 1
;transfer block phases
ph2 = 0
ph20= 1 
ph3 = 3; any phase
ph21= 0
;readout/receiver phase
ph4 = 0 2 2 0 1 3 3 1; any phase
ph31= 0 2 2 0 1 3 3 1
#endif

#ifdef PCYCLE5
;excitation, states, TPPI
ph1 = 0 0 0 0 2 2 2 2
ph10= 0 0 0 0 0 0 0 0 2 2 2 2 2 2 2 2
;shape pulse phase (z-filter)
ph8 = 0 1 3 2
ph9 = 2 3 0 1
;transfer block phases
ph2 = 0
ph20= 1 3 3 1
ph3 = 3 2 3 2; any phase
ph21= 0 0 2 2
;readout/receiver phase
ph4 = 0; any phase
ph31= 0 2 2 0 2 0 0 2 2 0 0 2 0 2 2 0
#endif

#ifdef PCYCLE6
;excitation, states, TPPI
ph1 = 0 0 0 0 2 2 2 2
ph10= 0 0 0 0 0 0 0 0 2 2 2 2 2 2 2 2
;shape pulse phase (z-filter)
ph8 = 0 1 3 2
ph9 = 2 3 0 1
;transfer block phases
ph2 = 0
ph20= 1 3 3 1
ph3 = 3 2 3 2; any phase
ph21= 0 0 2 2
;readout/receiver phase
ph4 = 0 0 0 0 1 1 1 1; any phase
ph31= 0 2 2 0 3 1 1 3 2 0 0 2 1 3 3 1
#endif

#ifdef PCYCLE7
;excitation, states, TPPI
ph1 = 0 0 0 0 2 2 2 2 2 2 2 2 0 0 0 0
ph10= 0
;shape pulse phase (z-filter)
ph8 = 0 1 0 1 1 0 1 0 3 2 3 2 2 3 2 3
ph9 = 2 3 2 3 3 2 3 2 1 0 1 0 0 1 0 1
;transfer block phases
ph2 = 0
ph20= 1 3 3 1
ph3 = 3 2 3 2; any phase
ph21= 0 0 2 2
;readout/receiver phase
ph4 = 0 ; any phase
ph31= 0 2 2 0 2 0 0 2 2 0 0 2 0 2 2 0
#endif

;pl0 : 0W
;pl1 : power level for pulse (default)
;p11: 190u
;p13: 550u
;p14: 200u
;p15: 200u
;p23: 1st inversion pulse for dephasing (z-filter)
;p24: 2nd inversion pulse for dephasing (z-filter)
;spnam11: xy-BEBOP_190u_RF10kHz...
;spnam12: xy-BEBOP_tr_190u_RF10kHz...
;spnam13: jc08_BEBOP_z-y_550u_BW10...
;spnam14: URx180_200_0.5u_BW10...
;spnam15: jc20_BURBOP_x90.0deg...
;spnam16: jc04_BEBOP_yz_550u...
;spnam23: 1st inversion pulse for dephasing (z-filter)
;spnam24: 2nd inversion pulse for dephasing (z-filter)
;sp11: 10 kHz: Power level for 25us 90° pulse
;sp12: 10 kHz: Power level for 25us 90° pulse
;sp13: 20 kHz: Power level for 12.5us 90° pulse
;sp14: 20 kHz: Power level for 12.5us 90° pulse
;sp15: 20 kHz: Power level for 12.5us 90° pulse
;sp16: 20 kHz: Power level for 12.5us 90° pulse
;sp23: Power level for dephasing pulse (z-filter)
;sp24: Power level for dephasing pulse (z-filter)

;p16: homospoil/gradient pulse                         [1 msec]
;d0 : incremented delay (2D)                           [3 usec]
;d1 : relaxation delay; 1-5 * T1
;d4 : 1/(4J(HH))
;d11: delay for disk I/O                               [30 msec]
;d16: delay for homospoil/gradient recovery
;cnst2: > J(HH); 30 Hz
;inf1: 1/SW(X) = 2 * DW(X)
;in0: 1/(2 * SW(X)) = DW(X)
;nd0: 2
;NS: 2 * n
;DS: 16
;td1: number of experiments
;FnMODE: States-TPPI, TPPI, States or QSEQ

;for z-only gradients:
;gpz1: 7.2% z-filter gradient
;gpz2: -7.5% z-filter gradient
;gpz3: -17.9% purge gradient

;use gradient files:
;gpnam3: SMSQ10.100

;Processing

;PHC0(F1): 0
;PHC1(F1): -180
;FCOR(F1): 1

;$Id: clipcosysp,v 0.9 2015/07/20 16:34:17 mk Exp $
